@echo off

rem $Id$

set DUMMY=Dummy
if not !DUMMY!==Dummy cmd.exe /e:on /v:on /c %0
if not !DUMMY!==Dummy goto eof

setlocal

rem Copyleft 2012 Clazzes.org
rem
rem Install LibO-Server service
rem

rem
rem Find the application home.
rem
rem %~dp0 is location of current script under NT
set _REALPATH=%~dp0

rem Decide on the libreoffice binary.
if not "%PROCESSOR_ARCHITEW6432%"=="AMD64" (
if not "%PROCESSOR_ARCHITECTURE%"=="AMD64" goto :x86
)

set _LIBO_SERVER_EXE=%_REALPATH%libo-server.exe
if exist "%_LIBO_SERVER_EXE%" goto :startup

:x86
set _LIBO_SERVER_EXE=%_REALPATH%libo-server.exe

rem
rem Install the libo-server as service.
rem
:startup

set LIBO_USER=""

set libo_server_conf=%_REALPATH%..\etc\libo-server.conf

for /F "tokens=2 Delims=[=]" %%v in ('findstr /B LIBO_USER "!libo_server_conf!"') do set LIBO_USER=%%v

set LIBO_SERVICE=libo-server

if not !LIBO_USER!=="" (
  set USER_ARGS=/user !LIBO_USER!
  echo Installing %LIBO_SERVICE% running as !LIBO_USER!
) else (
  set USER_ARGS=
  echo Installing %LIBO_SERVICE% running as LocalService
)

echo "%_LIBO_SERVER_EXE%" /install %LIBO_SERVICE% /pretty "LibreOffice Server daemon." /desc "The LibreOffice Server daemon allows to use LibreOffice to convert between several supported document formats." !USER_ARGS!
"%_LIBO_SERVER_EXE%" /install %LIBO_SERVICE% /pretty "LibreOffice Server daemon." /desc "The LibreOffice Server daemon allows to use LibreOffice to convert between several supported document formats." !USER_ARGS!
if errorlevel 1 goto :showerror

echo Starting %LIBO_SERVICE%
net start %LIBO_SERVICE%

goto eof

:showerror
echo "Some ERROR occured."

:eof